Simple Emacs Window Persistence

By jcscoobyrs on Fri, 04/09/2010 - 10:59

So I've been using Emacs for a long time now but most recently, I've started using the new NextStep/Cocoa support for Mac OS X. Basically, it replaces the old Carbon support with OS X's newer Cocoa APIs. The reason for doing this was an attempt to find an OS X Emacs application instead of using the terminal emacs implementation. Nothing was wrong with the terminal version but I wanted to have more flexibility, specifically with OS X's Spaces feature. One of the first things I noticed was, well, every time I opened Emacs.app, I had to reposition and resize my Emacs window because the maximize button didn't consume all available screen real estate. That being said, I whipped up a very simple alternative using Emacs Lisp (elisp). Below are the two elisp functions, one to persist your window geometry at Emacs close and another to load the geometry at Emacs startup, and the hooks to wire the functions up to the necessary hooks to have it all work:

;; Custom functions/hooks for persisting/loading frame geometry upon save/load
(defun save-frameg ()
  "Gets the current frame's geometry and saves to ~/.emacs.frameg."
  (let ((frameg-font (frame-parameter (selected-frame) 'font))
        (frameg-left (frame-parameter (selected-frame) 'left))
        (frameg-top (frame-parameter (selected-frame) 'top))
        (frameg-width (frame-parameter (selected-frame) 'width))
        (frameg-height (frame-parameter (selected-frame) 'height))
        (frameg-file (expand-file-name "~/.emacs.frameg")))
    (with-temp-buffer
      ;; Turn off backup for this file
      (make-local-variable 'make-backup-files)
      (setq make-backup-files nil)
      (insert
       ";;; This file stores the previous emacs frame's geometry.\n"
       ";;; Last generated " (current-time-string) ".\n"
       "(setq initial-frame-alist\n"
       "      '((font . \"" frameg-font "\")\n"
       (format "        (top . %d)\n" (max frameg-top 0))
       (format "        (left . %d)\n" (max frameg-left 0))
       (format "        (width . %d)\n" (max frameg-width 0))
       (format "        (height . %d)))\n" (max frameg-height 0)))
      (when (file-writable-p frameg-file)
        (write-file frameg-file)))))
 
(defun load-frameg ()
  "Loads ~/.emacs.frameg which should load the previous frame's geometry."
  (let ((frameg-file (expand-file-name "~/.emacs.frameg")))
    (when (file-readable-p frameg-file)
      (load-file frameg-file))))
 
;; Special work to do ONLY when there is a window system being used
(if window-system
    (progn
      (add-hook 'after-init-hook 'load-frameg)
      (add-hook 'kill-emacs-hook 'save-frameg)))

All you have to do is get this into your ~/.emacs file and things just work. What you'll notice is after you have this code in place, open Emacs, reposition your window and resize its geometry. Next time you open Emacs, it should remember the last window geometry/location.

Known Issues

This implementation does not work for new Emacs windows spawned from a running Emacs (If you know a hook I could use so that opening a new window will run load_frameg, let me know.)

Share this post: